Alternative Power sources - Re: Seasonal heat storage

Author

Re: Seasonal heat storage

nicksanspam@ece.villanova.edu

2006-11-27, 9:25 am

http://www.beaufortcourt.com/rec/David-Lloyd-Jones.pdf

>On page 25 of 51 they show the thermal store. It looks like an
>inverted pyramid shape lined and covered.

With lots of insulation (thermal conductance Gh = 160 Btu/h-F in line 250),
a house with no solar gain in Rochester NY might heat itself with the help of
a 24'-diameter $500 outdoor swimming pool with a shallow transparent dome
over a draindown foamboard cover/collector over a half-spherical bottom with
a membrane liner, with no insulation between the liner and the soil.

10 SCREEN 9:KEY OFF:PI=4*ATN(1)
20 DIM IH(12),TA(12),TD(12)
30 DATA 500,23.6,30.9,750,24.6,32.5,1080,34.3,42.7
40 DATA 1460,45.9,55.9,1750,57.1,67.8,1930,65.1,75.8
50 DATA 1910,70.2,80.7,1630,68,78.1,1250,61.7,71.8
60 DATA 840,51.1,60.5,500,40.5,47.8,400,29.1,35.8
70 FOR M=1 TO 12'read NREL monthly average weather data for Rochester NY
80 READ IH(M),TA(M),TM'solar gain on ground, average temp, max temp
90 TD(M)=(TA(M)+TM)/2'average daytime temp (F)
100 NEXT M
110 RW=12!'radius of water half-sphere (feet)
120 AW=PI*RW^2'half-sphere cover area (ft^2)
130 NC=2'number of transparent covers
140 VW=2/3*PI*RW^3'volume of water (ft^3)
150 C(0)=62.33*VW'thermal capacitance of water (Btu/F)
160 T(0)=47.6'deep ground temp (F)
170 RS=4'US R-value of dry soil (F-ft^2-h/Btu-ft)
180 CS=31'heat capacity of soil (Btu/ft^3-F)
190 FOR SHEL=1 TO 10'concentric half-spheres
200 ASHEL=2*PI*(RW+SHEL-.5)^2'shell area (ft^2)
210 G(SHEL)=ASHEL/RS'shell thermal conductance (Btu/h-F)
220 C(SHEL)=ASHEL*CS'shell thermal capacitance (Btu/F)
230 T(SHEL)=47.6'deep ground temp (F)
240 NEXT SHEL
250 GH=160'house conductance (Btu/h-F)
260 FOR Y=1 TO 10'years
270 FOR SHEL=0 TO 9
280 TMIN(SHEL)=1000'initialize min water temp (F)
290 TMAX(SHEL)=0'initialize max water temp (F)
300 NEXT SHEL
310 FOR M=1 TO 12'months
320 GAIN=.9^NC*IH(M)*AW'solar gain (Btu/day)
330 HEAT=(70-TA(M))*GH'house heat (Btu/h)
340 IF HEAT<0 THEN HEAT=0
350 FOR D=1 TO 30'days
360 LOSS=10*(T(0)-TD(M))*AW/NC'loss (Btu/day)
370 IF GAIN<LOSS THEN SGAIN=0 ELSE SGAIN = (GAIN-LOSS)/24
380 FOR H=1 TO 24'hours
390 HEATIN=SGAIN-HEAT+(T(1)-T(0))*G(1)
400 T(0)=T(0)+HEATIN/C(0)'new water temp (F)
410 IF T(0)>170 THEN T(0)=170'limit upper storage temp (F)
420 IF T(0)<TMIN(0) THEN TMIN(0)=T(0)'min shell temp (F)
430 IF T(0)>TMAX(0) THEN TMAX(0)=T(0)'max shell temp (F)
440 FOR I=1 TO 9'adjust soil shell temps (F)
450 HEATIN=(T(I-1)-T(I))*G(I)+(T(I+1)-T(I))*G(I+1)
460 T(I)=T(I)+HEATIN/C(I)'new shell temp (F)
470 IF T(I)<TMIN(I) THEN TMIN(I)=T(I)'min shell temp (F)
480 IF T(I)>TMAX(I) THEN TMAX(I)=T(I)'max shell temp (F)
490 NEXT I
500 NEXT H
510 NEXT D
520 NEXT M
530 NEXT Y
540 FOR I=0 TO 9
550 PRINT I,TMIN(I),TMAX(I),C(I)*(TMAX(I)-80)
560 NEXT I
Useful stored
Shell # Tmin (F) Tmax (F) energy (Btu)

0 83.00486 170 2.030215E+07 (water)
1 81.16523 148.554 2086386 (next foot of soil)
2 78.23145 130.2627 1784246 ...
3 74.28682 114.5937 1416688
4 69.82622 101.0944 987125.7
5 65.4075 89.36602 496666.2
6 61.23306 79.06806 -55591.5
7 57.35332 69.92654 -671527.6
8 53.79474 61.73191 -1353020
9 50.55239 54.32846 -2101364

The water might store about 20 million Btu/year. The soil (modeled as 9
concentric 1'-thick half-spherical shells) might add 30% to that.

Nick

OldNick

2006-11-27, 9:25 am

On 27 Nov 2006 07:54:51 -0500, nicksanspam@ece.villanova.edu wrote:

Wha....

>10 SCREEN 9:KEY OFF:PI=4*ATN(1)
>20 DIM IH(12),TA(12),TD(12)
>30 DATA 500,23.6,30.9,750,24.6,32.5,1080,34.3,42.7
>40 DATA 1460,45.9,55.9,1750,57.1,67.8,1930,65.1,75.8
>50 DATA 1910,70.2,80.7,1630,68,78.1,1250,61.7,71.8
>60 DATA 840,51.1,60.5,500,40.5,47.8,400,29.1,35.8
>70 FOR M=1 TO 12'read NREL monthly average weather data for Rochester NY
>80 READ IH(M),TA(M),TM'solar gain on ground, average temp, max temp
>90 TD(M)=(TA(M)+TM)/2'average daytime temp (F

nicksanspam@ece.villanova.edu

2006-11-27, 1:25 pm

OldNick <nsremovable@iinet.net.au> wrote:
[color=darkred]
>nicksanspam@ece.villanova.edu wrote:
>
>Wha....
>

The hourly TMY2 version works better, with fewer solar collection hours
and a 288 vs 160 Btu/h-F house conductance in line 160...

10 SCREEN 9:KEY OFF:PI=4*ATN(1)
20 RW=12!'radius of water half-sphere (feet)
30 AW=PI*RW^2'half-sphere cover area (ft^2)
40 NC=2'number of transparent covers
50 VW=2/3*PI*RW^3'volume of water (ft^3)
60 C(0)=62.33*VW'thermal capacitance of water (Btu/F)
70 T(0)=47.6'deep ground temp (F)
80 RS=4'US R-value of soil (F-ft^2-h/Btu-ft)
90 CS=31'heat capacity of soil (Btu/ft^3-F)
100 FOR SHEL=1 TO 10'concentric half-spheres
110 ASHEL=2*PI*(RW+SHEL-.5)^2'shell area (ft^2)
120 G(SHEL)=ASHEL/RS'shell thermal conductance (Btu/h-F)
130 C(SHEL)=ASHEL*CS'shell thermal capacitance (Btu/F)
140 T(SHEL)=47.6'deep ground temp (F)
150 NEXT SHEL
160 GH=288'house conductance (Btu/h-F)
170 FOR SHEL=0 TO 9
180 TMIN(SHEL)=1000'initialize min water temp (F)
190 NEXT SHEL
200 FOR Y=1 TO 10'years
210 OPEN "14768.tm2" FOR INPUT AS #1'NREL TMY2 file name (Rochester, NY)
220 LINE INPUT#1,S$'read header
230 FOR H=1 TO 8760'hour of year
240 LINE INPUT#1,S$
250 TDB=VAL(MID$(S$,68,4))*.18+32'dry bulb temp (F)
260 IGLOH=VAL(MID$(S$,18,4))*.317'global horizontal radiation (Btu/ft^2)
270 GAIN=.9^NC*IGLOH*AW'solar gain (Btu/day)
280 LOSS=(T(0)-TDB)*AW/NC'loss (Btu/h)
290 IF GAIN<LOSS THEN GAIN=0'no solar gain
300 HEAT=(70-TDB)*GH'house heat (Btu/h)
310 IF HEAT<0 THEN HEAT=0'no house heat required
320 HEATIN=GAIN-HEAT+(T(1)-T(0))*G(1)'water heat gain (Btu)
330 T(0)=T(0)+HEATIN/C(0)'new water temp (F)
350 IF T(0)>170 THEN T(0)=170'limit upper storage temp (F)
355 IF Y<10 GOTO 380'skip min/max monitoring till end
360 IF T(0)<TMIN(0) THEN TMIN(0)=T(0)'min shell temp (F)
370 IF T(0)>TMAX(0) THEN TMAX(0)=T(0)'max shell temp (F)
380 FOR I=1 TO 9'adjust shell temps (F)
390 HEATIN=(T(I-1)-T(I))*G(I)+(T(I+1)-T(I))*G(I+1)
400 T(I)=T(I)+HEATIN/C(I)'new shell temp (F)
410 IF Y<10 GOTO 440
420 IF T(I)<TMIN(I) THEN TMIN(I)=T(I)'min shell temp (F)
430 IF T(I)>TMAX(I) THEN TMAX(I)=T(I)'max shell temp (F)
440 NEXT I
450 NEXT H
460 CLOSE #1
470 NEXT Y
480 FOR I=0 TO 9
490 PRINT I,TMIN(I),TMAX(I),C(I)*(TMAX(I)-80)
500 NEXT I
Useful stored
Shell # Tmin (F) Tmax (F) energy (Btu)

0 80.28647 170 2.030215E+07 (water)
1 78.84882 148.5229 2085439 (next foot of soil)
2 76.20151 130.3937 1788897 ...
3 72.50547 114.8902 1428833
4 68.56764 101.4804 1005188
5 64.56051 89.75243 517157.2
6 60.63129 79.39645 -36002.58
7 56.93566 70.17133 -655208.7
8 53.53288 61.88943 -1341353
9 50.42808 54.40375 -2095201

Nick

LinkBot